MP3 Spieler wie TonieBox

//Ruft eine Library auf um mit dem DFPlayer arbeiten zu können.
#include "Arduino.h"
#include "SoftwareSerial.h"
#include "DFRobotDFPlayerMini.h"

//Ruft eine Library auf um mit dem RFID-KIT arbeiten zu können.
#include <SPI.h>
#include <MFRC522.h>
#define SS_PIN 10
#define RST_PIN 9
MFRC522 mfrc522(SS_PIN, RST_PIN);

SoftwareSerial mySoftwareSerial(6, 7); // RX, TX
DFRobotDFPlayerMini myDFPlayer;

//Teilt den Namen der Taster jeweils eine Zahl/Pin zu.
int TasteVolumeUP = 3;
int TasteVolumeDOWN = 5;
int Pause = 4;

//Speichert ob ein Taster ein- oder ausgeschaltet ist.
int STATUSup = 0;
int STATUSdown = 0;
int STATUSpause = 0;

int Volume = 15;  //Speichert die eingestellte Lautstärke
int iPause = 0;   //Besagt ob das Audio pausiert ist oder nicht.

void setup()
{
  SPI.begin();
  mfrc522.PCD_Init();

  mySoftwareSerial.begin(9600);
  Serial.begin(115200);

  pinMode(TasteVolumeUP, INPUT);
  pinMode(TasteVolumeDOWN, INPUT);
  pinMode(Pause, INPUT);

  if (!myDFPlayer.begin(mySoftwareSerial)) {  //SoftwareSerial für die Kommunikation mit mp3
    Serial.println(F("Fehler:"));
    Serial.println(F("1.Verbindung zum MP3 Modul herstellen!"));
    Serial.println(F("2.Speicherkarte einlegen!"));
    while (true);
  }
  myDFPlayer.volume(Volume);  //Lautstärke zwischen 0 und 30 einstellen. Als Startwert haben wir der Variablen den Wert 15 zugeordnet.
}


void loop()
{
  STATUSup = digitalRead(TasteVolumeUP);
  STATUSdown = digitalRead(TasteVolumeDOWN);
  STATUSpause = digitalRead(Pause);

  // Nun wird geprüft, was passieren soll, wenn die Pausetaste gedrückt wird. Wenn das Gerät abspielt, soll es pausieren. Wenn es sich jedoch bereits in der Pause befindet, soll die Pause aufgehoben werden.
  if (STATUSpause == HIGH)
  {
    if (iPause == 0)
    {
      myDFPlayer.pause();
      delay(500);
      iPause = 1;
    }
    else if (iPause == 1)
    {
      myDFPlayer.start();
      delay(500);
      iPause = 0;
    }

  }

  if (STATUSup == HIGH && Volume < 30) // Wenn Lautstärke+ gedrückt wird, und die maximale Lautstärke (Wert 30) noch nicht erreicht ist, dann soll die Lautstärke angehoben werden.
  {
    Volume = Volume + 5;
    myDFPlayer.volume(Volume);
    Serial.println(Volume);
    delay(500);
  }

  if (STATUSdown == HIGH && Volume > 0)  // Wenn Lautstärke- gedrückt wird, und die minimale Lautstärke (Wert 0) noch nicht erreicht ist, dann soll die Lautstärke gesenkt werden.
  {
    Volume = Volume - 5;
    myDFPlayer.volume(Volume);
    Serial.println(Volume);
    delay(500);
  }

  // Hier wird der RFID-TAG ausgelesen

  if ( ! mfrc522.PICC_IsNewCardPresent())
  {
    return;
  }

  if ( ! mfrc522.PICC_ReadCardSerial())
  {
    return;
  }

  long code = 0;
  for (byte i = 0; i < mfrc522.uid.size; i++)
  {
    code = ((code + mfrc522.uid.uidByte[i]) * 10);
  }

  // Die Kartennummer soll am Seriellen Monitor angezeigt werden.
  Serial.print("Die Kartennummer lautet: ");
  Serial.println(code);

  // ACHTUNG!!! Nur in unserem Fall lautet der Code des ersten RFID-TAG 446250. Den Code des eigenen RFID-TAG muss zunächst selbst ermittelt werden, ion dem man diesen Code hochläd und den Code des RFID-TAGS am seriellen Monitor abliest.

  if (code == 446250) //Wenn der Code 446250 lautet, dann Spiele die MP3-Datei mit dem Namen 0002.mp3
  {
    iPause = 0;
    myDFPlayer.play(2); // An dieser Stelle wird die mp3-Datei "0002.mp3" aufgerufen
    delay(600);
  }

  if (code == 1427270) //Wenn der Code 1427270 lautet, dann Spiele die MP3-Datei mit dem Namen 0001.mp3
  {
    iPause = 0;
    myDFPlayer.play(1); //An dieser Stelle wird die mp3-Datei "0001.mp3" aufgerufen
    delay(600);
  }

}